Ci siamo occupati, in tutorial precedenti, di alcuni metodi di calcolo finanziari che possono essere di aiuto nella scelta tra ipotesi alternative di investimento e precisamente del metodo del pay back period, del metodo del valore attuale netto e del metodo del TIR .In questo tutorial analizziamo il metodo del Valore Attuale e lo confrontiamo con il metodo del VAN; faremo uso di alcuni esempi pratici elaborati nella cartella di lavoro in allegato.
La funzione VA di Excel
Il Valore Attuale (da ora in poi VA) calcola il valore attuale di una serie di flussi di cassa costanti generati in periodi futuri (che si presumono della stessa ampiezza, quali ad esempio, semestri o anni) attraverso l’utilizzo di un tasso di sconto (o meglio di un tasso di attualizzazione).
La funzione VA, appartenente alla categoria delle funzioni Finanziarie, è costituita da cinque argomenti ed ha la seguente sintassi:
Sintassi della funzione VA
=VA(tasso_int;periodi;pagamento;valore_futuro;tipo)
L’argomento tasso_int è il tasso di interesse relativo all’unità temporale considerata; pertanto, se i flussi sono di tipo semestrale ed il tasso di attualizzazione è annuale, occorrerà dividere quest’ultimo per due, se i flussi sono quadrimestrali il tasso annuale va diviso per 3, etc.
L’argomento periodi è dato dal numero totale dei pagamenti, mentre l’argomento pagamento è dato dal flusso di cassa costante pagato o riscosso in ogni periodo.
L’argomento valore_futuro è dato dal flusso di cassa eventuale relativo all’ultimo periodo in aggiunta al valore del pagamento.
Infine, l’argomento tipo, indica il tempo nel quale vengono generati i flussi di cassa: un valore pari a uno (1) indica che gli importi dei flussi di cassa sono generati all’inizio dei singoli periodi, mentre un valore pari a zero (0) o la sua omissione, indica che i flussi si riferiscono alla fine dei singoli periodi.
Da notare che se non è presente il flusso di cassa addizionale (valore_futuro) e i pagamenti avvengono alla fine di ogni periodo, il Valore attuale può essere calcolato utilizzando la funzione VA in maniera semplificata, ovvero escludendo gli ultimi due argomenti:
Funzione VA semplificata
=VA(tasso_int;periodi;pagamento)
Facciamo qualche esempio pratico per comprendere l’utilizzo della funzione VA.
Primo esempio
Supponiamo di voler acquistare un nuovo impianto del costo di 200.000 € che consenta di realizzare prodotti dalla cui vendita, alla fine di ogni anno, si ottengano introiti netti costanti pari a 50.000 €; supponiamo inoltre che la vita utile dell’impianto sia di 5 anni e che il valore di realizzo sia pari a zero (0). Dato un tasso di attualizzazione del 10%, determiniamo se l’investimento è conveniente da un punto di vista economico-finanziario.
Avendo dato per ipotesi che gli introiti vengono riscossi alla fine di ogni anno (periodo) e che non sono previsti introiti aggiuntivi (valore_futuro) al termine del quinto anno, possiamo utilizzare la funzione VA nella sua veste semplificata, ovvero:
=VA(10%;5;50000)
Il risultato della funzione è espresso con segno negativo (-189.539,34 €) e deriva dalla seguente motivazione: per ricevere 50.000 € alla fine di ogni anno, per i prossimi 5 anni (considerato un tasso di attualizzazione del 10%) occorre spendere oggi -€ 189.539,34 euro. Quindi, dato che l’impianto costa 200.000 €, possiamo concludere che l’investimento non è conveniente.
Trasferiamo i dati dell’esempio all’interno di un foglio di calcolo come nella rappresentato in figura.
Utilizzando i riferimenti alle altre celle del prospetto, nella cella B8 possiamo scrivere la funzione:
=-VA(B6;B5;B3)
Da notare che la funzione è stata scritta anteponendo il segno algebrico meno (-) in maniera da ottenere un VA con segno positivo, mentre la convenienza dell’investimento (cella B9) è stata calcolata sottraendo al VA (con segno positivo) il costo dell’impianto; in questo modo, se il risultato della formula della cella B9 (=B8-A2) è positivo, significa che c’è convenienza nell’investimento, altrimenti, se negativo, significa che l’acquisto dell’impianto non è conveniente.
Secondo esempio
Supponiamo, riferendoci all’esempio precedente, che al termine del quinto anno l’impianto possa essere venduto realizzando 15.000 €. Risulta ancora non conveniente l’investimento da un punto di vista economico-finanziario? La funzione VA da utilizzare in questa seconda ipotesi è la seguente:
=VA(10%;5;50000;15000)
Alla funzione utilizzata in precedenza è stato aggiunto il quarto argomento (valore_futuro) che esprime, appunto, il valore di realizzo dell’impianto al termine dell’ultimo “pagamento”.
Il risultato della funzione è pari a -198.853,16 € e, quindi, ancora una volta, l’acquisto dell’impianto non risulta essere conveniente.
Da notare che una analisi superficiale avrebbe portato a ritenere conveniente l’investimento: difatti, l’introito aggiuntivo di 15.000 € sembra coprire la “non convenienza” nell’acquisto dell’impianto data da poco meno di 10.500 € (200000-189.539,34); l’errore di questa analisi risiede nel fatto che non si considera che il ricavato dalla vendita dell’impianto avviene tra cinque anni e quindi, oggi ha un valore inferiore!
Riutilizzando il foglio di calcolo dell’esempio precedente, nella cella B8 dobbiamo inserire la funzione:
=-VA(B6;B5;B3;B4)
Terzo esempio
Nei due esempi precedenti abbiamo ipotizzato la riscossione dei flussi di cassa netti derivanti dalla vendita dei prodotti (50.000) alla fine di ognuno dei cinque anni di vita utile dell’impianto; per rendere maggiormente attendibile il risultato della funzione VA, possiamo ipotizzare (come solitamente avviene nelle realtà aziendali) che i flussi di cassa vengano generati mensilmente: pertanto, anziché introitare 50.000 € alla fine di ogni anno, supponiamo di introitare un dodicesimo (1/12) ogni mese. Data questa ipotesi, verifichiamo se risulta conveniente l’investimento nell’impianto.
Nell’esempio proposto l’argomento periodi della funzione VA è pari a 60 (5 *12) mesi, l’argomento tasso_int deve essere rapportato ai mesi (10%/12) ed, infine, l’argomento pagamento deve essere suddiviso per 12 (50.000/12). Pertanto la funzione da utilizzare risulta essere:
=VA(10%/12;5*12;50000/12;15000)
Il risultato della funzione VA (pari a -205.222,53 €) indica che se i flussi di cassa vengono generati mensilmente piuttosto che annualmente (sempre ipotizzando la vendita dell’impianto alla fine dei cinque anni) l’acquisto dell’impianto a 200.000 € risulta conveniente dal punto di vista economico-finanziario. Riutilizzando il prospetto creato in precedenza, la funzione da inserire nella cella B8 è:
=-VA(B6/12;B5*12;B3/12;B4)
Da notare che il maggiore valore attuale rispetto a quello calcolato nell’esempio 2 deriva dal fatto che introitare 50.000 alla fine di ogni anno è finanziariamente meno conveniente che introitare un dodicesimo ogni mese!
La funzione VAN o la funzione VA?
La funzione VAN consente di utilizzare flussi di cassa differenti per ogni periodo sia in relazione all’importo che al segno algebrico; inoltre, l’attualizzazione del valore attuale netto considera sempre che i flussi di cassa vengano riscossi (o pagati) alla fine di ogni periodo.
Diversamente, la funzione VA ammette solo flussi di cassa costanti e dello stesso segno ma consente di considerare l’ipotesi di pagamenti anticipati all’inizio di ogni periodo; permette, inoltre, di considerare un eventuale pagamento (o riscossione) in aggiunta all’ultimo periodo di riferimento.
Relativamente alla valutazione degli investimenti (le considerazioni sono differenti nel caso della valutazione economica-finanziaria di finanziamenti), pertanto, è preferibile utilizzare la funzione VAN nelle ipotesi di flussi di cassa differenti per ogni periodo o con segni algebrici alterni, e la funzione VA nelle altre ipotesi.
Ovviamente, in presenza di flussi di cassa costanti posticipati e dello stesso segno, entrambe le funzioni portano ad uno stesso risultato.
Quarto esempio
Riprendiamo i dati relativi all’Esempio 2 e verifichiamo che le due funzioni VAN e VA determinano lo stesso risultato.
Nella cella B8 del prospetto avevamo utilizzato la funzione:
=-VA(B6;B5;B3;B4)
Prima di calcolare il Valore Attuale Netto riassumiamo, innanzitutto, la sua sintassi:
=VAN(tasso_int;valore_1;valore_2;…;valore_n)
L’argomento tasso_int è il tasso di attualizzazione, mentre gli altri argomenti della funzione (valore_1, valore_2, …) rappresentano gli importi riscossi o pagati alla fine di ogni periodo.
Il Valore Attuale netto nell’ipotesi specifica è dato dalla seguente funzione
=VAN(10%;50000;50000;50000;50000;50000+15000)
ovvero attualizzando al tasso del 10% i flussi di cassa ottenuti dall’investimento (il flusso di cassa relativo al quinto periodo è maggiorato del valore delle dismissioni dell’impianto).
Pertanto, utilizzando i riferimenti alle altre celle del prospetto, nella cella B11 scriveremo:
=VAN(B6;B3;B3;B3;B3;B3+B4)
Come risultato della cella B11 si ottiene un valore di 198.853,16 €, pari a quello ottenuto con la funzione VA nella cella B8.
Abbiamo poc’anzi affermato che è preferibile utilizzare la funzione VAN nelle ipotesi di flussi di cassa differenti per ogni periodo o con segni algebrici alterni e la funzione VA nelle altre ipotesi.
A conferma di tale tesi, facciamo solo notare che se si consideravano i flussi di cassa mensili dell’esempio 3 invece che quelli annuali ripresi dall’esempio 2, sarebbe stato necessario utilizzare l’argomento “B3/12” per ben 60 volte e, quindi (visto la possibilità di inserire fino ad un massimo di 30 argomenti in una funzione), si sarebbe dovuto ricorrere (impropriamente) all’utilizzo di una matrice per ottenere lo stesso risultato della funzione VA.
