La maggior parte dei contratti di leasing stipulati tra imprese e fornitori di beni prevedono il pagamento di un maxicanone iniziale e di canoni periodici costanti con scandenze mensili o infraannuali (bimestrali, trimestrali, quadrimestrali).
Il versamento di una somma iniziale alla stipula del contratto consente di abbattere il costo dell’operazione di leasing in quanto la somma finanziata risulta essere minore (detto in altri termini, ad un maggiore maxicanone iniziale corrisponde, generalmente, un canone di importo minore o un numero di canoni complessivi minore).
In questo tutorial proponiamo un prospetto altamente dinamico che, dopo l’inserimento di pochi dati, crea automaticamente lo scadenziario del bene in leasing e calcola, ad ogni fine esercizio, il valore del risconto attivo (ovvero di quella quota di costo già pagata ma di competenza futura) da riportare negli esercizi contabili successivi.
Utilizzare il modello
Per utilizzare il modello è sufficiente inserire i dati relativi al bene in leasing nelle celle delle righe 3 e 4 del prospetto.
In particolare, nella cella B3 va inserita una breve descrizione del bene, nella cella B4 la data del contratto corrispondente al pagamento del maxicanone iniziale (qualora le due date non coincidono, occorre inserire la data del pagamento del maxicanone); nella cella D3 va inserito il maxicanone mentre nella cella D4 va l’importo del canone di leasing periodico; nella cella F3 deve essere inserito il numero complessivo di rate previste contrattualmente ad eccezione della prima rata relativa al maxicanone, infine, nella cella F4 va indicata la tipologia di rata (se vengono versati canoni mensili di leasing occorre inserire 12, se le rate sono bimestrali occorre inserire 6, se trimestrali occorre inserire 4, e così via).
I dati inseriti nell’esempio riportato in figura si riferiscono alla stipulazione di un contratto in leasing per un Macchinario che prevede in data 10 maggio, il pagamento di un maxicanone di € 4.000,00 ed il pagamento di 12 canoni leasing bimestrali dell’importo di € 350,00 ciascuno.
Dopo l’inserimento dei dati viene generato in automatico lo scadenziario del bene in leasing che riporta nelle sei colonne, rispettivamente:
- il numero progressivo delle rate a partire dalla rata iniziale, ovvero quella del pagamento del maxicanone, che riporta il valore 0
- la scadenza, ovvero la data di pagamento dei singoli canoni leasing
- l’esercizio contabile di riferimento in corrispondenza della rata con scadenza il 31/12 o con scadenza “a cavallo” tra due esercizi
- l’importo dei singoli canoni, da utilizzare nel conto canoni leasing in Partita Doppia; l’importo visualizzato nella prima riga della tabella (riga 7) corrisponde al maxicanone iniziale previsto contrattualmente
- l’importo di competenza economica dei singoli canoni leasing
- il valore del risconto attivo da contabilizzare a fine anno in Partita Doppia per stornare la parte di costo di competenza del futuro esercizio contabile (quest’ultimo è costituito da una quota di maxicanone pagato all’inizio del contratto ed, eventualmente, dalla quota di canone leasing che interessa un periodo temporale “a cavallo” tra due esercizi contabili)
Costruire il modello
Analizziamo le procedure che permettono la creazione in automatico dello scadenziario dei beni in leasing; la lunghezza di quest’ultimo dipende dal numero delle rate previste contrattualmente alle quali deve essere aggiunta la data iniziale relativa al pagamento del maxicanone.
Nella cella A7 è stata utilizzata la formula:
=SE(O(B4=””;D3=””;F3=””;F4=””;D4=””);””;0)
La funzione SE consente di visualizzare nella cella il numero zero (0) solo se sono stati inseriti tutti i dati relativi al contratto di leasing nella parte superiore del prospetto (ad eccezione della cella B2 destinata ad accogliere la descrizione del bene preso in leasing); ciò consente di evitare la comparsa di messaggi di errori o la comparsa, nelle altre colonne dello scadenziario di numeri negativi.
Nella cella A8 è stata utilizzata la formula:
=SE(O($B$4=””;$D$3=””;$F$3=””;$F$4=””;$D$4=””);””;SE($F$3>A7;A7+1;””))
La formula, composta da due funzioni SE nidificate, può essere letta in questo modo:
SE non sono stati inseriti i dati relativi al contratto RESTITUISCI una cella vuota, ALTRIMENTI SE il numero complessivo delle rate è maggiore del valore inserito nella cella A7, RESTITUISCI quest’ultimo valore aumentato di una unità ALTRIMENTI (ovvero, se abbiamo raggiunto il numero complessivo di rate) RESTITUISCI una cella vuota.
La formula è stata costruita con dei riferimenti assoluti in maniera da poter essere copiata verso il basso per trascinamento (tutte le formule della tabella che riporta lo scadenziario sono state inserite fino alla riga 47 del foglio di calcolo).
La colonna B del prospetto deve visualizzare le date delle scadenze periodiche dei singoli canoni leasing; queste ultime dipendono del tipo di rata (semestrale, quadrimestrale, etc.) indicata nella cella F6 e devono arrestarsi in corrispondenza dell’ultima rata riportata nella colonna A.
Nella cella B7 è stata utilizzata la formula:
=SE(A7=””;””;DATA(ANNO($B$4);MESE($B$4)+A7*12/$F$4;GIORNO($B$4)))
La funzione SE consente di visualizzare la data di scadenza delle singole rate solo se esiste un valore nella cella A7 e, pertanto, quando verrà trascinata nelle celle sottostanti, mostrerà delle date fino a quando esisterà un valore nella serie della colonna A.
Per visualizzare le date delle singole scadenze dei canoni leasing abbiamo utilizzato la funzione DATA e, come argomento di quest’ultima, le funzioni ANNO, MESE, GIORNO.
La funzione DATA è composta da tre argomenti (rispettivamente anno, mese e giorno) ed è particolarmente indicata nella realizzazione di serie di date in quanto permette di “traslare” automaticamente i valori dei mesi o dei giorni in eccesso: ad esempio, la funzione =DATA(2009;16;20) restituirà la data 20/04/2010 in quanto trasla i 4 mesi eccedenti (ai 12 che compongono un anno) sull’anno successivo.
Le funzioni ANNO, MESE e GIORNO, utilizzate come argomenti della funzione DATA, restituiscono rispettivamente l’anno il mese e il giorno di un numero seriale o di una data indicata come argomento; ad esempio, la funzione =ANNO(31/12/09) restituirà 2009, la funzione =MESE(31/12/09) restituirà 12 mentre la funzione =GIORNO(31/12/09) restituirà 31.
Torniamo alla funzione DATA inserita nella cella B7.
DATA(ANNO($B$4);MESE($B$4)+A7*12/$F$4;GIORNO($B$4))
Come primo argomento della funzione DATA abbiamo utilizzato la funzione ANNO($B$4) che estrapola l’anno della data nella quale è stato stipulato il contratto e versato il maxicanone (inserita nella cella B4); come secondo argomento abbiamo utilizzato la formula MESE($B$4)+A7*12/$F$4 che consente di calcolare il totale dei mesi complessivamente trascorsi dalla prima rata (si ricorda che per il meccanismo della traslazione, verranno aggiornati gli anni quando i mesi superano 12); come terzo argomento abbiamo utilizzato la funzione GIORNO($B$4) per richiamare il giorno della stipula del contratto (inserito nella data della cella B4) o meglio, del pagamento del maxicanone iniziale.
La funzione è stata successivamente copiata verso il basso, sempre fino alla riga 47 del foglio di calcolo.
La terza colonna della tabella visualizza la data di chiusura dell’esercizio contabile in corrispondenza del “salto” di date da un anno all’altro; tali valori consentiranno, successivamente, di calcolare il Risconto Attivo da contabilizzare a fine esercizio.
La formula inserita nella cella C7 (e successivamente copiata per trascinamento fino alla cella C47) è:
=SE(B8=””;””;SE(ANNO(B8)>ANNO(B7);DATA(ANNO(B7);12;31);””))
La formula, costruita con due funzioni SE nidificate e con le funzioni ANNO e DATA, può essere letta in questo modo:
SE la cella B8 è vuota (ovvero se siamo in corrispondenza dell’ultimo canone leasing) RESTITUISCI una cella vuota, ALTRIMENTI SE l’anno della data inserita in B8 è maggiore dell’anno inserito nella data della cella B7 (ANNO(B8)>ANNO(B7)) RESTITUISCI la data del 31/12 relativa all’anno della data inserita in B7 (DATA(ANNO(B7);12;31)) ALTRIMENTI (ovvero, se le due date appartengono allo stesso anno solare e quindi siamo in corrispondenza di canoni infra-annuali) inserisci una etichetta vuota.
La colonna D visualizza gli importi dei canoni periodici del contratto di leasing a partire dal maxicanone pagato a inizio contratto.
In D7, pertanto, è stata utilizzata la formula:
=SE(A7=””;””;D3)
che subordina la trascrizione dell’importo del maxicanone (inserito nella cella D3) all’esistenza di una serie numerica nella cella A7. Nella cella D8 è stata invece inserita (e copiata fino alla cella D47) la formula:
=SE(A8=””;””;$D$4)
che richiama l’importo del canone leasing, sempre se nella prima cella della riga (A8) esiste un valore.
La colonna E indica, per ogni singola rata, l’importo del canone leasing di competenza economica; quest’ultimo si calcola dividendo il costo complessivo del contratto di leasing per il numero di rate, compresa quella iniziale del maxicanone e consente, successivamente, di determinare il valore del risconto attivo al 31/12 di ogni esercizio contabile.
Pertanto, nella cella E7 è stata inserita la funzione:
=SE(A7=””;””;($D$3+$D$4*$F$3)/(($F$3+1)))
La funzione, copiata per trascinamento fino alla cella E47, visualizza il risultato della somma tra il maxicanone (D3) e i canoni periodici (D4*F3) diviso il numero di rate complessive (F3+1) se la cella A7 contiene un valore.
Il risconto attivo, visualizzato nelle celle della colonna F, si calcola per differenza tra la somma dei canoni leasing (colonna D) e quella dei canoni di competenza (colonna E) di ciascuno esercizio contabile.
Pertanto, nella cella F7 si è utilizzata la formula:
=SE(C7=””;””;SOMMA($D$7:D7)-SOMMA($E$7:E7))
La funzione restituisce la differenza tra la somma dei canoni leasing e quella dei canoni di competenza se la cella C7 contiene un valore diverso da vuoto; pertanto, copiando verso il basso la formula fino alla cella F47, si otterrà il valore del risconto attivo sono in corrispondenza delle date di fine esercizio.
Personalizzare il modello
Il modello è stato costruito copiando tutte le formule fino alla riga 47 e, pertanto, consente di accogliere uno scadenziario di beni in leasing fino ad un massimo di 40 rate; se si rende necessario utilizzare un numero maggiore di rate è sufficiente selezionare le celle dell’ultima riga contenente le formule (riga 47) e copiare queste ultime verso il basso trascinando il quadratino di riempimento della cella F47.
