L’ammortamento di un cespite è una particolare procedura contabile che serve ad imputare parte del costo di un bene ai diversi esercizi contabili nei quali il bene viene utilizzato. La normativa fiscale sull’ammortamento dei cespiti prevede diverse possibilità di ripartire tale costo negli anni a seconda del valore del bene e del suo utilizzo concreto in azienda (si parla, in questi casi, di ammortamento ordinario, ammortamento accelerato, ammortamento in un’unica soluzione, …).
=> Leggi la disciplina fiscale in cado di Furto di merci
Fatta eccezione per l’acquisto di beni di modico valore, per il quale si applica normalmente l’ammortamento in un’unica soluzione, i metodi maggiormente utilizzati in azienda sono quello “ordinario” e quello “anticipato”.
In questo tutorial viene proposto un modello per il calcolo, in automatico, di un piano di ammortamento “ordinario”, tale metodo si basa su alcuni “coefficienti di ammortamento” stabiliti dal Ministero dell’Economia, differenti per tipologia di bene (ai beni che hanno una “vita utile” più ampia, quali ad esempio, fabbricati e terreni, si applicano coefficienti minori in maniera tale che il periodo di ammortamento risulti più diluito nel tempo) e prevede che per il primo esercizio (l’anno nel quale è stato acquistato il bene) il coefficiente stesso deve essere “ridotto alla metà”.
Come utilizzare il modello
L’utilizzazione del modello è molto semplice in quanto è sufficiente inserire pochi dati (una breve descrizione del bene nella cella F3, il valore di acquisto nella cella H4 e il coefficiente di ammortamento previsto dalla tabella ministeriale nella cella H5) per ottenere, in automatico, il “piano di ammortamento” completo del bene con l’indicazione di tutti i valori necessari da iscrivere, anno per anno, in bilancio.
Figura 1. Esempio di piano di ammortamento
Come costruire il modello proposto
Ma vediamo nel dettaglio come è stato costruito il modello e quali “accorgimenti” sono stati usati per rendere quest’ultimo “flessibile” ovvero idoneo ad essere utilizzato per qualunque cespite presente in azienda.
Per determinare il periodo complessivo di ammortamento, nella cella H6 è stata utilizzata la formula:
=SE(H5=””;0;ARROTONDA(1/H5+1;0))
che può essere letta in questo modo: se non è stato indicato alcun coefficiente di ammortamento (ovvero, se la cella H5 è vuota) restituisci uno zero (0), altrimenti arrotonda a 0 cifre decimali il risultato che si ottiene dividendo 1 per il coefficiente e sommando 1.
Analizziamo quest’ultimo calcolo, che a prima vista potrebbe sembrare poco chiaro, con un esempio numerico.
=> Leggi anche l’ammortamento anticipato di cespiti
Supponiamo di avere un coefficiente di ammortamento del 20% ovvero, matematicamente, pari a 0,20; dividendo 1 per 0,20 si ottiene il numero 5 che sono gli anni che servono per ammortizzare completamente il bene (se ammortizzo il bene ogni anno per il 20%, dopo cinque anni lo avrò ammortizzato completamente – 20%*5 =100%). Ora, poiché, per disposizione normativa, al primo anno il bene deve essere ammortizzato applicando la metà del coefficiente (nell’esempio numerico, 10%) sarà necessario, per ammortizzare completamente il bene, aggiungere un ulteriore periodo contabile, e ciò spiega l’utilizzo del “+1” nella formula.
Soffermiamo ora la nostra attenzione sulla parte tabellare del modello. Il problema da affrontare era quello di creare un’area “flessibile” per adattare il modello a qualunque tipo di ammortamento (un coefficiente del 20% richiede, come abbiamo visto, un prospetto con 6 periodi, ma un coefficiente del 5% richiede un prospetto di 21 periodi!): il problema è stato risolto utilizzando una “colonna di servizio”, la colonna A, nella quale è stata inserita una serie da 1 a 35 (non sono previsti nelle tabelle ministeriali, se non in casi eccezionali, coefficienti inferiori al 3%) e, come ora vedremo, richiamata in alcune formule del modello.Figura 2. Modello “flessibile”
Nella cella B9 è stata utilizzata la formula:
=SE(O($H$6=””;A9>$H$6);””;A9)
che può essere letta in questo modo: se il periodo di ammortamento (H6) è vuoto oppure la cella A9 è maggiore di tale periodo, restituisci una cella vuota (le doppie virgolette della funzione SE), altrimenti restituisci il valore contenuto nella cella A9. Trascinando verso il basso tale formula per 35 righe (quindi fino alla cella B43), vedremo comparire una serie di numeri che inizia con 1 e termina con il numero corrispondente ai periodi inseriti in H6.
=> Vedi la guida all’ammortamento dei cespiti con Access
In C9 è stata utilizzata la formula =SE(B9<>””;$H$4;0) ed è stata successivamente ricopiata verso il basso sempre fino alla cella C43. La formula consente di ritrascrivere il valore di acquisto del bene contenuto in H4 soltanto se la cella alla sua sinistra non è vuota (ovvero, contiene i periodi contabili di ammortamento).
Nella cella D9 è stata utilizzata la formula =SE(B9=””;0;H5/2) che consente di trascrivere il coefficiente di ammortamento ridotto alla metà (H5/2) nel caso in cui la cella B9 contenga un valore.
La cella D10 contiene una formula differente, anch’essa ricopiata fino alla cella D43. Per comprenderne la struttura analizziamo dapprima le formule contenute nella colonna E che, riga per riga, sommano le percentuali di ammortamento (% cumulate) (anticipiamo subito che la percentuale cumulata di ammortamento serve solo per determinare l’aliquota da applicare all’ultimo periodo di ammortamento).
In E9 è stata utilizzata la formula =D9 (la prima percentuale cumulata è uguale alla prima aliquota del prospetto), mentre nella cella E10 è stata utilizzata la formula =E9+D10 ed è stata ricopiata verso il basso: in questo modo vedremo comparire la somma delle percentuali di ammortamento che, dall’ultimo esercizio contabile e fino alla fine del prospetto, avrà un valore sempre pari a 100% (ciò in quanto le rispettive celle della colonna D avranno, come vedremo, un valore pari a zero dalla riga successiva a quella relativa all’ultimo periodo di ammortamento).
Torniamo alla colonna D. Nella cella D10, è stata utilizzata la funzione:
=SE(B10=””;0;SE(B10=$H$6;1-E9;$H$5))
che può essere letta in questo modo: se la cella B10 è vuota scrivi uno zero (0), altrimenti se è uguale alla cella H6 (ovvero se ci troviamo nell’ultimo periodo di ammortamento) scrivi il coefficiente di ammortamento “residuo” (1-E9), altrimenti scrivi il valore “standard” del coefficiente (H5).
Le ultime tre colonne del prospetto non presentano particolari problemi.
La “Quota di ammortamento” annuale del bene contenuta nella cella F9 è stata calcolata arrotondando a due cifre decimali la moltiplicazione tra il costo storico del bene (D9) e l’aliquota di ammortamento (C9) nel seguente modo:
=SE(B9=””;0;ARROTONDA(D9*C9;2));
la formula è stata ricopiata fino alla cella F43.
Il “Fondo di ammortamento” è stato calcolato sommando, anno per anno, le quote di ammortamento già maturate; nella cella G9 è stata utilizzata la formula =F9 mentre nella cella G10 è stata utilizzata la funzione
=SE(B10=””;0;G9+F10)
e successivamente è stata ricopiata fino alla cella G43.
Il “Valore residuo” è stato calcolato come differenza tra il costo storico e il fondo ammortamento già maturato; in H9 è stata inserita la funzione =SE(B9=””;0;C9-G9) e, successivamente, è stata ricopiata verso il basso.
Tutte queste formule sono state inserite all’interno della funzione SE che subordina la visualizzazione del risultato all’esistenza di un valore nella colonna B: in questo modo la parte tabellare del modello si ridimensiona automaticamente in base al numero degli esercizi contabili necessari per ammortizzare, per intero, il cespite.
L’ultima operazione compiuta sul modello è stata quella di nascondere le “colonne di servizio” (colonna A e colonna E) utilizzate per rendere flessibile la parte tabellare dello stesso: per visualizzarle è sufficiente selezionare l’intero foglio di calcolo e utilizzare il comando Colonne/Scopri del menu “Formato”.
